Вернуться к библиотеке SD

isDirectory()

Описание

Директории (или папки) технически являются особым видом файлов. Данная функция позволяет проверить, является ли указанный файл директорией или нет.

Синтаксис

file.isDirectory()

Параметры

file: экземпляр класса File (возвращаемый функцией file.open())

Возвращаемые значения

boolean

Пример

#include <SD.h>

File root;

void setup()
{
  Serial.begin(9600);
  pinMode(10, OUTPUT);

  SD.begin(10);

  root = SD.open("/");

  printDirectory(root, 0);

  Serial.println("done!");
}

void loop()
{
  // после первоначальной настройки ничего не происходит.
}

void printDirectory(File dir, int numTabs) {
   while(true) {

     File entry =  dir.openNextFile();
     if (! entry) {
       // больше нет файлов
       //Serial.println("**nomorefiles**");
       break;
     }
     for (uint8_t i=0; i<numTabs; i++) {
       Serial.print('\t');
     }
     Serial.print(entry.name());
     if (entry.isDirectory()) {
       Serial.println("/");
       printDirectory(entry, numTabs+1);
     } else {
       // у файлов есть размер, в отличие от директорий
       Serial.print("\t\t");
       Serial.println(entry.size(), DEC);
     }
   }
}

Смотрите также

• openNextFile()
• rewindDirectory()